Объект WScript.Shell метод SendKeys — имитация нажатия клавиш

Объект WScript.Shell метод SendKeys — имитация нажатия клавиш Объектная модель Windows Script Host

Всем привет, с вами автор блога scriptcoding.ru. Сегодня мы затронем такую тему как имитация нажатия клавиш программными средствами с помощью метода SendKeys класса WScript.Shell.

SendKeys – имитация нажатия клавиш – теоретические основы

Метод SendKeys, который позволяет имитировать нажатие клавиш и их комбинаций. Метод SendKeys объекта WScript.Shell является по своей природе слепым, так как он не позволяет указать то приложение, которому назначен ввод с клавиатуры, то есть, если мы сделаем попытку имитировать ввод фразы «привет мир», то она будет обрабатываться лишь тому приложениею, которое в данный момент являются активным. Если активным будет текстовый редактор – то в нем отобразится заданный текст, если антивирусная программа – то, скорее всего, никакой активности не произойдет.

Что бы использовать функцию Wscript SendKeys, нужно объявить переменную, которая будет хранить ссылку на объект WScript.Shell, а уже через эту переменную можно будет вызвать SendKeys.

Общая логика работы:

SendKeys(строка) – Видим, что мы в качестве аргумента должны передать строковое выражение, которое будет хранить имя клавиши или сочетание.

Что бы ввести просто символ или набор символов, мы всего-навсего прописываем их как строку, например: SendKeys(«привет мир»). Для ввода специальных клавиш (например, Enter, стрелки, функциональные клавиши и так далее), их название нужно заключить в фигурные скобки {}.

Ниже приведен список функциональных клавиш и их обозначение:

  • BACKSPACE -{BACKSPACE}, {BS} или {BKSP}
  • BREAK -{BREAK}
  • CAPS LOCK -{CAPSLOCK}
  • DEL или DELETE — {DELETE} или {DEL}
  • СТРЕЛКА ВНИЗ — {DOWN}
  • END -{END}
  • ENTER -{ENTER}или ~
  • ESC -{ESC}
  • HELP -{HELP}
  • HOME -{HOME}
  • INS или INSERT -{INSERT} или {INS}
  • СТРЕЛКА ВЛЕВО -{LEFT}
  • NUM LOCK -{NUMLOCK}
  • PAGE DOWN -{PGDN}
  • PAGE UP -{PGUP}
  • PRINT SCREEN -{PRTSC}
  • СТРЕЛКА ВПРАВО -{RIGHT}
  • SCROLL LOCK -{SCROLLLOCK}
  • TAB -{TAB}
  • СТРЕЛКА ВВЕРХ — {UP}
  • F1-{F1}
  • F2 -{F2}
  • F3 -{F3}
  • F4 -{F4}
  • F5 -{F5}
  • F6 -{F6}
  • F7 -{F7}
  • F8 -{F8}
  • F9- {F9}
  • F10 -{F10}
  • F11 -{F11}
  • F12 -{F12}
  • F13 -{F13}
  • F14 -{F14}
  • F15 -{F15}
  • F16 — {F16}

Если нужно указать сочетание специальных клавиш, то следует использовать следующие коды:

  • SHIFT — +
  • CTRL — ^
  • ALT — %

Также стоит помнить, что для ввода символов +, ^, %, ~, (, ) , {, } , [, ] их также нужно заключить в фигурные скобки.

Если есть необходимость имитации нажатия клавиши несколько раз подряд, то после нее через пробел прописывается количество, например: {n 20} – 20 раз подряд нажата клавиша n. Стоит учитывать один немаловажный момент, имитация нажатия клавиши не действует для приложений, которые не были разработаны специально для запуска в Microsoft Windows, например, командная строка.

SendKeys – имитация нажатия клавиш – приступаем к программированию

имитация нажатия клавиш с wscript sendkeys

Хорошо, с теорией разобрались, теперь давайте приступим к программированию. Давайте для начала рассмотрим следующий пример программного кода на языке vbscript:

'***************************************
' wscript shell SendKeys
' имитация нажатия клавиш в блокноте
' SendKeys.vbs
'***************************************
Option Explicit
 
Dim WshShell, my_arr(16), index
 
' Создаем ссылку на объект
Set WshShell = WScript.CreateObject("WScript.Shell")
 
'Определяем элементы массива
my_arr(0) = "Э"
my_arr(1) = "т"
my_arr(2) = "о"
my_arr(3) = "{ENTER 2}"
my_arr(4) = "п"
my_arr(5) = "р"
my_arr(6) = "о"
my_arr(7) = "с"
my_arr(8) = "т"
my_arr(9) = "о"
my_arr(10) = "й"
my_arr(11) = "{ENTER 2}"
my_arr(12) = "т"
my_arr(13) = "е"
my_arr(14) = "к"
my_arr(15) = "с"
my_arr(16) = "т"
 
' Запускаем программу блокнот
WshShell.Run "Notepad.exe", 1
 
'Делаем задержку в 2 секунды
WScript.Sleep 2000       
 
' Используем цикл для перебора элементов массива
For each index in my_arr
     ' Имитируем нажатие клавиши
     WshShell.SendKeys(index)
     ' Делаем задержку в 500 миллисекунд
     WScript.Sleep 500
Next
 
MsgBox "Конец теста!"

Видим, что тут мы создали массив символов my_arr(16), их количество составляет 17, так как нумерация элементов массива начинается с нуля. Вы можете возразить, а зачем формировать массив, если все можно прописать в одном строковом значении? Верно, но, цель сценария не просто отправить коды клавиш, а сделать задержку для каждого символа. Мы видим, что с помощью массива идет обработка каждого элемента, он передается методу SendKeys WScript Shell объекта, после идет задержка в 500 миллисекунд (WScript.Sleep 500), и так для каждого символа. Перед выполнением метода мы запускаем блокнот (WshShell.Run "Notepad.exe", 1) с помощью метода Run (подробно про метод Run я написал в статье «Объект WScript.Shell — метод Run«), поэтому, команды будут передаваться текстовому редактору. Как только все команды будут выполнены, появится сообщение (MsgBox "Конец теста!"), которое проинформирует, что сценарий завершил свою работу. На практике это выглядит так:

  • Запускается блокнот
  • Постепенно вводится текст «это»
  • Делаем два раза имитацию нажатия клавиши Enter ({ENTER 2})
  • Постепенно вводится текст «простой»
  • Нажимается два раза клавиша Enter ({ENTER 2})
  • Постепенно вводится текст «текст»
  • Появляется сообщение «Конец теста!»

А вот аналогичный пример, но уже на языке jscript:

//***************************************
// wscript shell SendKeys
// имитация нажатия клавиш в блокноте
// SendKeys.js
//***************************************
 
var WshShell, my_arr1 = new Array;
 
// Создаем ссылку на класс
WshShell = WScript.CreateObject("WScript.Shell");
 
//Формируем массив
my_arr1[0] = "Э";
my_arr1[1] = "т";
my_arr1[2] = "о";
my_arr1[3] = "{ENTER 2}";
my_arr1[4] = "п";
my_arr1[5] = "р";
my_arr1[6] = "о";
my_arr1[7] = "с";
my_arr1[8] = "т";
my_arr1[9] = "о";
my_arr1[10] = "й";
my_arr1[11] = "{ENTER 2}";
my_arr1[12] = "т";
my_arr1[13] = "е";
my_arr1[14] = "к";
my_arr1[15] = "с";
my_arr1[16] = "т";
 
// Запускаем текстовый редактор блокнот
WshShell.Run ("Notepad.exe", 1);
 
//Задержка в 2 секунды
WScript.Sleep (2000);    
 
// Используем цикл для перебора элементов массива
for (var index in my_arr1){
     // Имитируем нажатие клавиши
     WshShell.SendKeys(my_arr1[index]);
     // Делаем задержку в 500 миллисекунд
     WScript.Sleep (500);
}
 
WScript.Echo ("Конец теста!");

В примере на jscript я мог использовать более лаконичный стиль программирования для массива, но, решил этого не делать, что бы было наглядней видно, что и как. Важно, пока не появится сообщение о том, что сценарий выполнил работу, не переключатся на другие приложения, так как это может привести к неожиданным последствиям.

А вот еще один пример на vbscript:

'***************************************
' SendKeys wscript
' имитация нажатия клавиш в калькуляторе
' SendKeys_1.vbs
'***************************************
Option Explicit
 
Dim WshShell, my_arr2(5), index
 
' Создаем ссылку на класс
Set WshShell = WScript.CreateObject("WScript.Shell")
 
'математическая операция
' 100/2*0.5
my_arr2(0) = "100"
my_arr2(1) = "/"
my_arr2(2) = "2"
my_arr2(3) = "*"
my_arr2(4) = "0.5"
my_arr2(5) = "="
 
' Запускаем программу калькулятор
WshShell.Run "calc.exe", 1
 
'Делаем задержку в 2 секунды
WScript.Sleep 2000       
 
' последовательно вводим данные
For each index in my_arr2
     WshShell.SendKeys(index)
     WScript.Sleep 500
Next
 
' закрываем калькулятор
WshShell.SendKeys("%{F4}")
 
MsgBox "Операция выполнена!"
 
' Пытаемся запустить диспетчер задач
WshShell.SendKeys("^%{DELETE}")

В этом примере мы уже будем направлять с помощью метода SendKeys WScript Shell класса команды программе калькулятор – простая арифметика (100/2*0.5). В конце мы выполним имитацию нажатия комбинации клавиш «ALT + F4«, что бы закрыть калькулятор и выведем сообщение — «Операция выполнена!«. Далее мы снова попытаемся отправить в систему комбинацию «CTRL + ALT + DEL» (запуск диспетчера задач), но, ничего не выйдет, видимо эта комбинация не работает из-за соображений безопасности.

делаем имитацию нажатия клавиши - wscript shell sendkeys

Ну и пример на языке jscript:

//***************************************
// sendkeys wscript
// имитация нажатия клавиш в калькуляторе
// SendKeys_1.js
//***************************************
 
var WshShell, my_arr3 = new Array;
 
// Создаем ссылку на класс
WshShell = WScript.CreateObject("WScript.Shell");
 
//Формируем массив
my_arr3[0] = "100";
my_arr3[1] = "/";
my_arr3[2] = "2";
my_arr3[3] = "*";
my_arr3[4] = "0.5";
my_arr3[5] = "=";
 
// Запускаем текстовый редактор блокнот
WshShell.Run ("calc.exe", 1);
 
//Задержка в 2 секунды
WScript.Sleep (2000);     
 
// Используем цикл для перебора элементов массива
for (var index in my_arr3){
    WshShell.SendKeys(my_arr3[index]);
    WScript.Sleep (500);
}
 
// закрываем калькулятор
WshShell.SendKeys("%{F4}");
 
WScript.Echo ("Операция выполнена");
 
// Пытаемся запустить диспетчер задач
WshShell.SendKeys("^%{DELETE}");

Скачать архив с примерами

И так, давайте все подытожим… В этой статье мы рассмотрели функцию SendKeys класса WScript Shell, которая позволяет создавать имитацию нажатия клавиш, мы написали четыре программных кода – два на языке vbscript и два на языке jscript. Помним, что программный код работает под управлением сервера сценариев Windows Script Host.

Оцените статью
Технологии программирования и ведение блога
Добавить комментарий

  1. Кишиневский курьер

    Здравствуйте. Скажите пожалуйста, а как сымитировать нажатие клавиши Fn на ноутбуках? никак не могу найти ответа на данный вопрос. Заранее спасибо.

    Ответить
    1. Coding автор

      К сожалению, средствами Windows Script Host этого не сделать, видимо, во времена разработки сервера WSH функциональная клавиша Fn еще не использовалась и возможности имитировать что то типа Fn+F7 нет. Ну, по крайней мере, я тоже ничего не нашел. =(

      Ответить
    2. Справка

      Скачайте программу ATNSOFT Key Manager (платная, но есть портативная взломанная). Или бесплатную AutoHotkey, но тут сложнее, если вообще получится.

      Ответить
  2. Евгений

    Приветствую, Владимир! Подскажи почему метод SendKeys не работает с русской раскладкой, только на английской. На русской получается какая-то белиберда. Все что связано с кодировкой уже перепробовал. ОС — 7.

    Ответить
    1. Coding автор

      Евгений, на самом деле, функция SendKeys работает и с русской раскладкой, просто есть такой изъян: Допустим, мы передали функции русский символ ‘п’, при русской раскладке функция вернет именно этот символ, но, если раскладка английская, то функция вернет символ ‘g’. То есть, будет нажата та же клавиша, но в зависимости от раскладки, будет возвращаться тот символ, который к ней привязан.

      Ответить
  3. Руслан

    Приветствую, Владимир!
    подскажите, как запустить клавишу пробел на повтор?
    echo Chr(39)>%temp%\temp1.vbs
    echo Chr(39)>%temp%\temp2.vbs
    echo on error resume next > %temp%\temp.vbs
    echo Set S = CreateObject("Wscript.Shell") >> %temp%\temp.vbs
    echo set FSO=createobject("scripting.filesystemobject")>>%temp%\temp.vbs
    echo do >> %temp%\temp.vbs
    echo wscript.sleep 200 >> %temp%\temp.vbs
    echo s.sendkeys"{Space}" >> %temp%\temp.vbs
    echo loop>> %temp%\temp.vbs
    start %temp%\temp.vbs
    start %temp%\temp1.vbs
    start %temp%\temp2.vbs

    Ответить
  4. Vit

    А как прервать выполнение скрипта (например по нажатию Esc) ?

    Ответить
  5. Эдуард

    Здравствуйте Владимир, Как имитировать нажатия на клавиши дополнительной цифровой клавиатуры Ctrl + Shift + Num-?
    WshShell.SendKeys("(^+{NUMPAD-})") - не работает
    WshShell.SendKeys("(^+{SUBTRACT})") - не работает

    Ответить
    1. Александр

      на русской раскладе работает
      WshShell.SendKeys(«(^+k») // k — это Numpad +
      WshShell.SendKeys(«(^+m») // m — это Numpad —
      на английской раскладке я не смог найти символа numpad- и numpad+

      Ответить
  6. Артем

    А у меня вместо английских букв выводится что попало. Как сделать, что бы выводился текст английскими буквами?

    Ответить